實驗的目的：
把程序本身從Steppingstone復制到SDRAM處，然后跳轉到SDRAM中執(zhí)行

實驗的源程序：
@*************************************************************************
@ File：head.S
@ 功能：設置SDRAM，將程序復制到SDRAM，然后跳到SDRAM繼續(xù)執(zhí)行
@*************************************************************************

.equ MEM_CTL_BASE, 0x48000000
.equ SDRAM_BASE, 0x30000000

.text
.global _start
_start:
bl disable_watch_dog @ 關閉WATCHDOG，否則CPU會不斷重啟
bl memsetup @ 設置存儲控制器
bl copy_steppingstone_to_sdram @ 復制代碼到SDRAM中
ldr pc, =on_sdram @ 跳到SDRAM中繼續(xù)執(zhí)行
on_sdram:
ldr sp, =0x34000000 @ 設置堆棧
bl main
halt_loop:
b halt_loop

disable_watch_dog:
@ 往WATCHDOG寄存器寫0即可
mov r1, #0x53000000
mov r2, #0x0
str r2, [r1]
mov pc, lr @ 返回

copy_steppingstone_to_sdram:
@ 將Steppingstone的4K數據全部復制到SDRAM中去
@ Steppingstone起始地址為0x00000000，SDRAM中起始地址為0x30000000

mov r1, #0
ldr r2, =SDRAM_BASE
mov r3, #4*1024
1:
ldr r4, [r1],#4 @ 從Steppingstone讀取4字節(jié)的數據，并讓源地址加4
str r4, [r2],#4 @ 將此4字節(jié)的數據復制到SDRAM中，并讓目地地址加4
cmp r1, r3 @ 判斷是否完成：源地址等于Steppingstone的未地址？
bne 1b @ 若沒有復制完，繼續(xù)
mov pc, lr @ 返回

memsetup:
@ 設置存儲控制器以便使用SDRAM等外設

mov r1, #MEM_CTL_BASE @ 存儲控制器的13個寄存器的開始地址
adrl r2, mem_cfg_val @ 這13個值的起始存儲地址
add r3, r1, #52 @ 13*4 = 54
1: @這是數值1，專業(yè)術語叫局部標號，主要用于bne 1b這條語句
ldr r4, [r2], #4 @ 讀取設置值，并讓r2加4
str r4, [r1], #4 @ 將此值寫入寄存器，并讓r1加4
cmp r1, r3 @ 判斷是否設置完所有13個寄存器
bne 1b @ 若沒有寫成，繼續(xù)
mov pc, lr @ 返回

.align 4
mem_cfg_val:
@ 存儲控制器13個寄存器的設置值
.long 0x22011110 @ BWSCON @其實BWSCON這個寄存器的設置，主要是綜合了存儲控制器的其余BANK和外圍器件的連接
.long 0x00000700 @ BANKCON0 @一下這些寄存器的設置，都可以參考韋東山老師的書籍
.long 0x00000700 @ BANKCON1
.long 0x00000700 @ BANKCON2
.long 0x00000700 @ BANKCON3
.long 0x00000700 @ BANKCON4
.long 0x00000700 @ BANKCON5
.long 0x00018005 @ BANKCON6
.long 0x00018005 @ BANKCON7
.long 0x008C07A3 @ REFRESH
.long 0x000000B1 @ BANKSIZE
.long 0x00000030 @ MRSRB6
.long 0x00000030 @ MRSRB7

/**************************************************************************
led.c
**************************************************************************/

#define GPFCON (*(volatile unsigned long *)0x56000050)
#define GPFDAT (*(volatile unsigned long *)0x56000054)

#define GPF4_out (1<<(4*2))
#define GPF5_out (1<<(5*2))
#define GPF6_out (1<<(6*2))

void wait(volatile unsigned long dly)
{
for(; dly > 0; dly--);
}


int main(void)
{
unsigned long i = 0;

GPFCON = GPF4_out|GPF5_out|GPF6_out; // 將LED1,2,4對應的GPF4/5/6三個引腳設為輸出

while(1)
{
wait(30000);
GPFDAT = (~(i<<4)); // 根據i的值，點亮LED1,2,4
if(++i == 8)
i = 0;
}

return 0;

}

/**************************************************************************
Makefile
**************************************************************************/

sdram.bin : head.S leds.c
arm-linux-gcc -c -o head.o head.S
arm-linux-gcc -c -o leds.o leds.c
arm-linux-ld -Ttext 0x30000000 head.o leds.o -o sdram_elf
arm-linux-objcopy -O binary -S sdram_elf sdram.bin
arm-linux-objdump -D -m arm sdram_elf > sdram.dis
clean:
rm -f sdram.dis sdram.bin sdram_elf *.o

實驗的問題總結：
I.在這期間，存儲控制器起了一個什么作用？
在S3C2440/S3C2410中，對外引出的27根地址線ADDR0-ADDR26的訪問范圍只有128M，
CPU對外還引出了8根片選信號nGCS0-nGCS7，對應于BANK0-BANK7，當某一個片選信號拉低時，
對應的存儲控制器的BANK就被選中，而每個BANK都是和外部設備相連的，當CPU發(fā)出某一地址信號時，
它會通過讀取存儲控制器的中的寄存器的配置信息，從而就知道了如何去訪問外部的設備。我想這
大概就是存儲控制器的作用。

II.存儲控制器的BANK和SDRAM的Bank有什么區(qū)別？
存儲控制器的BANK
在TQ2440中，存儲控制器的BANK有8個，可以分別接8個不同的器件，通過片選信號使各個器件可以獨立開來訪問；
SDRAM的Bank
SDRAM的內部是一個存儲陣列。陣列就如同那么表格一樣，將數據“填”進去，你可以把它想象成一張表格。
和表格的檢索原理一樣，先指定一個行（Row），再指定一個列（Column），
我們就可以準確地找到所需要的單元格，這就是內存芯片尋址的基本原理。
對于內存，這個單元格可稱為存儲單元,那么這個表格（存儲陣列）叫什么呢？
它就是邏輯 Bank（Logical Bank，下文簡稱L-Bank），所以說，準備的說SDRAM的Bank叫L-Bank

III.怎么確定SDRAM是接存儲控制器的哪個BANK？還有就是每個BANK的對應的地址又是如何確定的？
關于SDRAM是接在存儲控制器的哪個BANK上的，可以通過開發(fā)板的原理圖的片選信號得知，因為片選信號和BANK是一一對應的；
當我們知道了SDRAM的是接在哪個BANK之后，接下來，我們如何知道這個SDRAM的地址呢？這主要是在S3C2440中的用戶手冊中
有介紹，對于每一個存儲控制器的BANK，其地址都已經規(guī)定好了。

IV.既然在Makefile中，指定的鏈接地址是：0x3000 0000 ,那按理說這些代碼段剛開始都是在SDRAM中執(zhí)行的啊，而剛開始SDRAM
又沒有初始化，這不矛盾么？
主要的原因是，在代碼段中，bl disable_watch_dog，bl memsetup，bl copy_steppingstone_to_sdram，因為都是相對跳轉，所以說這些都是位置無關的幾條指令，也就是說，這些代碼即使不在鏈接時所指定的運行時地址空間，也可以正確執(zhí)行，它是一段加載到任意地址空間都能正常執(zhí)行的特殊代碼。當程序運行到ldr pc, =on_sdram 條指令的時候，由于是取on_sdram的絕對地址，而其地址標號是在SDRAM中的，所以說，執(zhí)行完這條語句之后，程序就在SDRAM中運行了。關于這一點，可以百度一下位置無關代碼的知識。


注：可參考的書籍《嵌入式Linux應用開發(fā)完全手冊》