當(dāng)前位置：首頁(yè) > 單片機(jī) > 單片機(jī)

采用AT89C2051的6位電子鐘

時(shí)間：2010-02-01 10:48:16

關(guān)鍵字： AT89C2051 電子鐘 OV AC

手機(jī)看文章

掃描二維碼
隨時(shí)隨地手機(jī)看文章

[導(dǎo)讀]采用AT89C2051的6位電子鐘原理如下圖所示，只要硬件連接無(wú)誤，保證成功。另外圖中的SET按紐用于校準(zhǔn)時(shí)間。按住2秒以上進(jìn)入校準(zhǔn)時(shí)間狀態(tài)及換檔和退出，快速點(diǎn)觸用于調(diào)節(jié)時(shí)間數(shù)值。三極管采用9015即可。數(shù)碼管最好采用

采用AT89C2051的6位電子鐘原理如下圖所示，只要硬件連接無(wú)誤，保證成功。另外圖中的SET按紐用于校準(zhǔn)時(shí)間。按住2秒以上進(jìn)入校準(zhǔn)時(shí)間狀態(tài)及換檔和退出，快速點(diǎn)觸用于調(diào)節(jié)時(shí)間數(shù)值。三極管采用9015即可。數(shù)碼管最好采用紅色的共陽(yáng)型LED數(shù)碼管，亮度高些，因?yàn)槭菕呙璧娘@示方式，所以各個(gè)數(shù)碼管的abcdefg各腳采用了總線并聯(lián),改動(dòng)510歐姆的電阻可以改變顯示亮度。

電子鐘源程序

MCS51單片機(jī)匯編程序


 
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;; AT89C2051時(shí)鐘程序 ;;
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ; 定時(shí)器T0、T1溢出周期為50MS，T0為秒計(jì)數(shù)用， T1為調(diào)整時(shí)閃爍用，
        ; P3.7為調(diào)整按鈕，P1口 為字符輸出口，采用共陽(yáng)顯示管。
        ; ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;; 中斷入口程序 ;;
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
        ORG 0000H     ;程序執(zhí)行開(kāi)始地址
        LJMP START    ;跳到標(biāo)號(hào)START執(zhí)行
        ORG 0003H     ;外中斷0中斷程序入口
        RETI          ;外中斷0中斷返回
        ORG 000BH     ;定時(shí)器T0中斷程序入口
        LJMP INTT0    ;跳至INTTO執(zhí)行
        ORG 0013H     ;外中斷1中斷程序入口
        RETI          ;外中斷1中斷返回
        ORG 001BH     ;定時(shí)器T1中斷程序入口
        LJMP INTT1    ;跳至INTT1執(zhí)行
        ORG 0023H     ;串行中斷程序入口地址
        RETI          ;串行中斷程序返回
 
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;; 主 程 序 ;;
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
START:  MOV R0,#70H   ;清70H-7AH共11個(gè)內(nèi)存單元
        MOV R7,#0BH
CLEARDISP:
        MOV @R0,#00H
        INC R0
        DJNZ R7,CLEARDISP
        MOV 20H,#00H  ;清20H（標(biāo)志用）
        MOV 7AH,#0AH  ;放入"熄滅符"數(shù)據(jù)
        MOV TMOD,#11H ;設(shè)T0、T1為16位定時(shí)器
        MOV TL0,#0B0H ;50MS定時(shí)初值（T0計(jì)時(shí)用）
        MOV TH0,#3CH  ;50MS定時(shí)初值
        MOV TL1,#0B0H ;50MS定時(shí)初值（T1閃爍定時(shí)用）
        MOV TH1,#3CH  ;50MS定時(shí)初值
        SETB EA       ;總中斷開(kāi)放
        SETB ET0      ;允許T0中斷
        SETB TR0      ;開(kāi)啟T0定時(shí)器
        MOV R4,#14H   ;1秒定時(shí)用初值（50MS×20）
START1: LCALL DISPLAY ;調(diào)用顯示子程序
        JNB P3.7,SETMM1       ;P3.7口為0時(shí)轉(zhuǎn)時(shí)間調(diào)整程序
        SJMP START1   ;P3.7口為1時(shí)跳回START1
SETMM1: LJMP SETMM    ;轉(zhuǎn)到時(shí)間調(diào)整程序SETMM
 
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;; 1秒計(jì)時(shí)程序 ;;
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;T0中斷服務(wù)程序
INTT0:  PUSH ACC      ;累加器入棧保護(hù)
        PUSH PSW      ;狀態(tài)字入棧保護(hù)
        CLR ET0       ;關(guān)T0中斷允許
        CLR TR0       ;關(guān)閉定時(shí)器T0
        MOV A,#0B7H   ;中斷響應(yīng)時(shí)間同步修正
        ADD A,TL0     ;低8位初值修正
        MOV TL0,A     ;重裝初值（低8位修正值）
        MOV A,#3CH    ;高8位初值修正
        ADDC A,TH0
        MOV TH0,A     ;重裝初值（高8位修正值）
        SETB TR0      ;開(kāi)啟定時(shí)器T0
        DJNZ R4, OUTT0;20次中斷未到中斷退出
ADDSS:  MOV R4,#14H   ;20次中斷到（1秒）重賦初值
        MOV R0,#71H   ;指向秒計(jì)時(shí)單元（71H-72H）
        ACALL ADD1    ;調(diào)用加1程序（加1秒操作）
        MOV A,R3      ;秒數(shù)據(jù)放入A（R3為2位十進(jìn)制數(shù)組合）
        CLR C         ;清進(jìn)位標(biāo)志
        CJNE A,#60H,ADDMM
ADDMM:  JC OUTT0      ;小于60秒時(shí)中斷退出
        ACALL CLR0    ;大于或等于60秒時(shí)對(duì)秒計(jì)時(shí)單元清0
        MOV R0,#77H   ;指向分計(jì)時(shí)單元（76H-77H）
        ACALL ADD1    ;分計(jì)時(shí)單元加1分鐘
        MOV A,R3      ;分?jǐn)?shù)據(jù)放入A
        CLR C         ;清進(jìn)位標(biāo)志
        CJNE A,#60H,ADDHH
ADDHH:  JC OUTT0      ;小于60分時(shí)中斷退出
        ACALL CLR0    ;大于或等于60分時(shí)分計(jì)時(shí)單元清0
        MOV R0,#79H   ;指向小時(shí)計(jì)時(shí)單元（78H-79H）
        ACALL ADD1    ;小時(shí)計(jì)時(shí)單元加1小時(shí)
        MOV A,R3      ;時(shí)數(shù)據(jù)放入A
        CLR C         ;清進(jìn)位標(biāo)志
        CJNE A,#24H,HOUR
HOUR:   JC OUTT0      ;小于24小時(shí)中斷退出
        ACALL CLR0    ;大于或等于24小時(shí)小時(shí)計(jì)時(shí)單元清0
OUTT0:  MOV 72H,76H   ;中斷退出時(shí)將分、時(shí)計(jì)時(shí)單元數(shù)據(jù)移
        MOV 73H,77H   ;入對(duì)應(yīng)顯示單元
        MOV 74H,78H
        MOV 75H,79H
        POP PSW       ;恢復(fù)狀態(tài)字（出棧）
        POP ACC       ;恢復(fù)累加器
        SETB ET0      ;開(kāi)放T0中斷
        RETI          ;中斷返回
 
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;; 閃動(dòng)調(diào)時(shí) 程 序 ;;
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;T1中斷服務(wù)程序，用作時(shí)間調(diào)整時(shí)調(diào)整單元閃爍指示
INTT1:  PUSH ACC      ;中斷現(xiàn)場(chǎng)保護(hù)
        PUSH PSW
        MOV TL1, #0B0H;裝定時(shí)器T1定時(shí)初值
        MOV TH1, #3CH
        DJNZ R2,INTT1OUT      ;0.3秒未到退出中斷（50MS中斷6次）
        MOV R2,#06H   ;重裝0.3秒定時(shí)用初值
        CPL 02H       ;0.3秒定時(shí)到對(duì)閃爍標(biāo)志取反
        JB 02H,FLASH1 ;02H位為1時(shí)顯示單元"熄滅"
        MOV 72H,76H   ;02H位為0時(shí)正常顯示
        MOV 73H,77H
        MOV 74H,78H
        MOV 75H,79H
INTT1OUT:
        POP PSW       ;恢復(fù)現(xiàn)場(chǎng)
        POP ACC
        RETI          ;中斷退出
FLASH1: JB 01H,FLASH2 ;01H位為1時(shí)，轉(zhuǎn)小時(shí)熄滅控制
        MOV 72H,7AH   ;01H位為0時(shí)，"熄滅符"數(shù)據(jù)放入分
        MOV 73H,7AH   ;顯示單元（72H-73H），將不顯示分?jǐn)?shù)據(jù)
        MOV 74H,78H
        MOV 75H,79H
        AJMP INTT1OUT ;轉(zhuǎn)中斷退出
FLASH2: MOV 72H,76H   ;01H位為1時(shí)，"熄滅符"數(shù)據(jù)放入小時(shí)
        MOV 73H,77H   ;顯示單元（74H-75H），小時(shí)數(shù)據(jù)將不顯示
        MOV 74H,7AH
        MOV 75H,7AH
        AJMP INTT1OUT ;轉(zhuǎn)中斷退出
 
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;; 加1子 程 序 ;;
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
ADD1:   MOV A,@R0     ;取當(dāng)前計(jì)時(shí)單元數(shù)據(jù)到A
        DEC R0        ;指向前一地址
        SWAP A        ;A中數(shù)據(jù)高四位與低四位交換
        ORL A,@R0     ;前一地址中數(shù)據(jù)放入A中低四位
        ADD A,#01H    ;A加1操作
        DA A          ;十進(jìn)制調(diào)整
        MOV R3,A      ;移入R3寄存器
        ANL A,#0FH    ;高四位變0
        MOV @R0,A     ;放回前一地址單元
        MOV A,R3      ;取回R3中暫存數(shù)據(jù)
        INC R0        ;指向當(dāng)前地址單元
        SWAP A        ;A中數(shù)據(jù)高四位與低四位交換
        ANL A,#0FH    ;高四位變0
        MOV @R0,A     ;數(shù)據(jù)放入當(dāng)削地址單元中
        RET           ;子程序返回
 
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;; 清零程序 ;;
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;對(duì)計(jì)時(shí)單元復(fù)零用
CLR0:   CLR A         ;清累加器
        MOV @R0,A     ;清當(dāng)前地址單元
        DEC R0        ;指向前一地址
        MOV @R0,A     ;前一地址單元清0
        RET           ;子程序返回
 
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;; 時(shí)鐘調(diào)整程序 ;;
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;當(dāng)調(diào)時(shí)按鍵按下時(shí)進(jìn)入此程序
SETMM:  CLR ET0       ;關(guān)定時(shí)器T0中斷
        CLR TR0       ;關(guān)閉定時(shí)器T0
        LCALL DL1S    ;調(diào)用1秒延時(shí)程序
        JB P3.7,CLOSEDIS      ;鍵按下時(shí)間小于1秒，關(guān)閉顯示（省電）
        MOV R2,#06H   ;進(jìn)入調(diào)時(shí)狀態(tài)，賦閃爍定時(shí)初值
        SETB ET1      ;允許T1中斷
        SETB TR1      ;開(kāi)啟定時(shí)器T1
SET2:   JNB P3.7,SET1 ;P3.7口為0（鍵未釋放），等待
        SETB 00H      ;鍵釋放，分調(diào)整閃爍標(biāo)志置1
SET4:   JB P3.7,SET3  ;等待鍵按下
        LCALL DL05S   ;有鍵按下，延時(shí)0.5秒
        JNB P3.7,SETHH;按下時(shí)間大于0.5秒轉(zhuǎn)調(diào)小時(shí)狀態(tài)
        MOV R0,#77H   ;按下時(shí)間小于0.5秒加1分鐘操作
        LCALL ADD1    ;調(diào)用加1子程序
        MOV A,R3      ;取調(diào)整單元數(shù)據(jù)
        CLR C         ;清進(jìn)位標(biāo)志
        CJNE A,#60H,HHH       ;調(diào)整單元數(shù)據(jù)與60比較
HHH:    JC SET4       ;調(diào)整單元數(shù)據(jù)小于60轉(zhuǎn)SET4循環(huán)
        LCALL CLR0    ;調(diào)整單元數(shù)據(jù)大于或等于60時(shí)清0
        CLR C         ;清進(jìn)位標(biāo)志
        AJMP SET4     ;跳轉(zhuǎn)到SET4循環(huán)
CLOSEDIS:
        SETB ET0      ;省電（LED不顯示）狀態(tài)。開(kāi)T0中斷
        SETB TR0      ;開(kāi)啟T0定時(shí)器（開(kāi)時(shí)鐘）
CLOSE:  JB P3.7,CLOSE ;無(wú)按鍵按下，等待。
        LCALL DISPLAY ;有鍵按下，調(diào)顯示子程序延時(shí)削抖
        JB P3.7,CLOSE ;是干擾返回CLOSE等待
WAITH:  JNB P3.7,WAITH;等待鍵釋放
        LJMP START1   ;返回主程序（LED數(shù)據(jù)顯示亮）
SETHH:  CLR 00H       ;分閃爍標(biāo)志清除（進(jìn)入調(diào)小時(shí)狀態(tài)）
SETHH1: JNB P3.7,SET5 ;等待鍵釋放
        SETB 01H      ;小時(shí)調(diào)整標(biāo)志置1
SET6:   JB P3.7,SET7  ;等待按鍵按下
        LCALL DL05S   ;有鍵按下延時(shí)0.5秒
        JNB P3.7,SETOUT       ;按下時(shí)間大于0.5秒退出時(shí)間調(diào)整
        MOV R0,#79H   ;按下時(shí)間小于0.5秒加1小時(shí)操作
        LCALL ADD1    ;調(diào)加1子程序
        MOV A,R3
        CLR C
        CJNE A,#24H,HOUU      ;計(jì)時(shí)單元數(shù)據(jù)與24比較
HOUU:   JC SET6       ;小于24轉(zhuǎn)SET6循環(huán)
        LCALL CLR0    ;大于或等于24時(shí)清0操作
        AJMP SET6     ;跳轉(zhuǎn)到SET6循環(huán)
SETOUT: JNB P3.7,SETOUT1      ;調(diào)時(shí)退出程序。等待鍵釋放
        LCALL DISPLAY ;延時(shí)削抖
        JNB P3.7,SETOUT       ;是抖動(dòng)，返回SETOUT再等待
        CLR 01H       ;清調(diào)小時(shí)標(biāo)志
        CLR 00H       ;清調(diào)分標(biāo)志
        CLR 02H       ;清閃爍標(biāo)志
        CLR TR1       ;關(guān)閉定時(shí)器T1
        CLR ET1       ;關(guān)定時(shí)器T1中斷
        SETB TR0      ;開(kāi)啟定時(shí)器T0
        SETB ET0      ;開(kāi)定時(shí)器T0中斷（計(jì)時(shí)開(kāi)始）
        LJMP START1   ;跳回主程序
SET1:   LCALL DISPLAY ;鍵釋放等待時(shí)調(diào)用顯示程序（調(diào)分）
        AJMP SET2     ;防止鍵按下時(shí)無(wú)時(shí)鐘顯示
SET3:   LCALL DISPLAY ;等待調(diào)分按鍵時(shí)時(shí)鐘顯示用
        AJMP SET4
SET5:   LCALL DISPLAY ;鍵釋放等待時(shí)調(diào)用顯示程序（調(diào)小時(shí)）
        AJMP SETHH1   ;防止鍵按下時(shí)無(wú)時(shí)鐘顯示
SET7:   LCALL DISPLAY ;等待調(diào)小時(shí)按鍵時(shí)時(shí)鐘顯示用
        AJMP SET6
SETOUT1:LCALL DISPLAY ;退出時(shí)鐘調(diào)整時(shí)鍵釋放等待
        AJMP SETOUT   ;防止鍵按下時(shí)無(wú)時(shí)鐘顯示
 
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;; 顯示程序 ;;
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ; 顯示數(shù)據(jù)在70H-75H單元內(nèi)，用六位LED共陽(yáng)數(shù)碼管顯示，P1口輸出段碼數(shù)據(jù)，P3口作
        ; 掃描控制，每個(gè)LED數(shù)碼管亮1MS時(shí)間再逐位循環(huán)。
DISPLAY:MOV R1,#70H   ;指向顯示數(shù)據(jù)首址
        MOV R5,#0FEH  ;掃描控制字初值
PLAY:   MOV A,R5      ;掃描字放入A
        MOV P3,A      ;從P3口輸出
        MOV A,@R1     ;取顯示數(shù)據(jù)到A
        MOV DPTR,#TAB ;取段碼表地址
        MOVC A,@A+DPTR;查顯示數(shù)據(jù)對(duì)應(yīng)段碼
        MOV P1,A      ;段碼放入P1口
        LCALL DL1MS   ;顯示1MS
        INC R1        ;指向下一地址
        MOV A,R5      ;掃描控制字放入A
        JNB ACC.5,ENDOUT      ;ACC.5=0時(shí)一次顯示結(jié)束
        RL A          ;A中數(shù)據(jù)循環(huán)左移
        MOV R5,A      ;放回R5內(nèi)
        AJMP PLAY     ;跳回PLAY循環(huán)
ENDOUT: SETB P3.5     ;一次顯示結(jié)束，P3口復(fù)位
        MOV P1,#0FFH  ;P1口復(fù)位
        RET           ;子程序返回
TAB:    DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H,0FFH
        ;共陽(yáng)段碼表 "0""1""2" "3""4""5""6""7" "8""9""不亮"
 
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
        ;; 延時(shí)程序 ;;
        ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 
        ;1MS延時(shí)程序，LED顯示程序用
DL1MS:  MOV R6,#14H
DL1:    MOV R7,#19H
DL2:    DJNZ R7,DL2
        DJNZ R6,DL1
        RET
        ;20MS延時(shí)程序，采用調(diào)用顯示子程序以改善LED的顯示閃爍現(xiàn)象
DS20MS: ACALL DISPLAY
        ACALL DISPLAY
        ACALL DISPLAY
        RET
        ;延時(shí)程序，用作按鍵時(shí)間的長(zhǎng)短判斷
DL1S:   LCALL DL05S
        LCALL DL05S
        RET
DL05S:  MOV R3,#20H   ;8毫秒*32=0.196秒
DL05S1: LCALL DISPLAY
        DJNZ R3,DL05S1
        RET
 
        END

本站聲明：本文章由作者或相關(guān)機(jī)構(gòu)授權(quán)發(fā)布，目的在于傳遞更多信息，并不代表本站贊同其觀點(diǎn)，本站亦不保證或承諾內(nèi)容真實(shí)性等。需要轉(zhuǎn)載請(qǐng)聯(lián)系該專(zhuān)欄作者，如若文章內(nèi)容侵犯您的權(quán)益，請(qǐng)及時(shí)聯(lián)系本站刪除。

換一批

云頂新耀mRNA新冠候選疫苗取得積極頂線結(jié)果

云頂新耀宣布其合作伙伴Providence Therapeutics Holdings Inc.的mRNA新冠候選疫苗PTX-COVID19-B在評(píng)估其安全性、耐受性和免疫原性的II期研究中取得了積極的頂線結(jié)果。云頂新耀...

關(guān)鍵字： VI OV IDE CE

[快訊]

貝萊德和先鋒等金融機(jī)構(gòu)將繼續(xù)投資化石燃料

世界上最大的兩家資產(chǎn)管理公司貝萊德(BlackRock)和先鋒(Vanguard)等金融機(jī)構(gòu)已在英國(guó)一項(xiàng)問(wèn)詢(xún)中表示，它們將繼續(xù)投資化石燃料，并且不認(rèn)同氣候變化計(jì)劃要求停止新的煤炭、石油和天然氣投資的觀點(diǎn)。貝萊德是試圖采取...

關(guān)鍵字： CK 天然氣 AN AC

[快訊]

美國(guó)Syncromune獲祐和醫(yī)藥瘤內(nèi)免疫療法權(quán)益

百奧賽圖（北京）醫(yī)藥科技股份有限公司的全資子公司祐和醫(yī)藥科技（北京）有限公司宣布與臨床階段的美國(guó)生物制藥公司Syncromune達(dá)成協(xié)議，共同開(kāi)發(fā)和商業(yè)化基于Syncrovax?技術(shù)的瘤內(nèi)免疫療法。Syncrovax?平...

關(guān)鍵字： ROM OV

[產(chǎn)業(yè)新聞]

TUV南德獲EcoVadis全球企業(yè)社會(huì)責(zé)任評(píng)級(jí)金獎(jiǎng)

慕尼黑2022年10月17日 /美通社/ -- TUV南德意志集團(tuán)（以下簡(jiǎn)稱(chēng)"TUV南德"）在EcoVadis全球企業(yè)社會(huì)責(zé)任評(píng)級(jí)中以總分71分榮獲金獎(jiǎng)。...

關(guān)鍵字： OV ADIS BSP COM

[產(chǎn)業(yè)新聞]

亞馬遜云科技打造"3+3價(jià)值成就體系" 強(qiáng)化合作伙伴網(wǎng)絡(luò) 與合作伙伴攜手共贏未來(lái)

北京2022年10月14日 /美通社/ -- 2022年10月14日，亞馬遜云科技舉辦一年一度的中國(guó)合作伙伴峰會(huì)。本屆峰會(huì)以"價(jià)值成就探索無(wú)限"為主題，面向合作伙伴推出"3+3價(jià)值成就體系...

關(guān)鍵字：亞馬遜網(wǎng)絡(luò) AC MARKET

[快訊]

珀金埃爾默推出業(yè)界首創(chuàng)細(xì)胞分析解決方案

珀金埃爾默日前推出Cellaca PLX圖像式細(xì)胞分析系統(tǒng)，這是業(yè)界第一款能讓研究人員在單個(gè)自動(dòng)化工作流中實(shí)現(xiàn)對(duì)細(xì)胞樣本多個(gè)關(guān)鍵質(zhì)量屬性進(jìn)行分析和評(píng)估的臺(tái)式平臺(tái)，包括對(duì)細(xì)胞性質(zhì)、質(zhì)量和數(shù)量的分析評(píng)估。擁有尖端技術(shù)的Cel...

關(guān)鍵字： AC EXCEL 硬件自動(dòng)化

[產(chǎn)業(yè)新聞]

尼達(dá)尼布治療兒童和青少年進(jìn)展性纖維化性間質(zhì)性肺疾病全球III期臨床試驗(yàn)結(jié)果公布

本文重點(diǎn)： 8月25日發(fā)表在《歐洲呼吸雜志》上的最新臨床試驗(yàn)數(shù)據(jù)表明，在患有進(jìn)展性纖維化性間質(zhì)性肺疾病的兒童和青少年中，以體重為基礎(chǔ)的尼達(dá)尼布給藥方案與在成人患者中觀察到的暴露量相當(dāng)，并顯示了可接受的安全性。...

關(guān)鍵字： RS INTER BSP OV

[產(chǎn)業(yè)新聞]

珀金埃爾默推出業(yè)界首創(chuàng)細(xì)胞分析解決方案

加速簡(jiǎn)化細(xì)胞和基因治療的研發(fā)及制造流程 Cellaca® PLX圖像式細(xì)胞分析儀帶來(lái)工作流程的革新，一站式滿足多個(gè)關(guān)鍵質(zhì)量屬性的分析上海2022年10月12日 /美通社/ -- 致力于以創(chuàng)新技術(shù)打造更健康世...

關(guān)鍵字： AC 自動(dòng)化 NEX EXCEL

[產(chǎn)業(yè)新聞]

Airwallex空中云匯完成1億美元E2輪融資，估值仍保持55億美元

上海2022年10月11日 /美通社/ -- 全球領(lǐng)先金融科技公司Airwallex空中云匯今日宣布完成1億美元E2輪融資。現(xiàn)有投資方Square Peg、Salesforce Ventures、紅杉中國(guó)、Lone Pi...

關(guān)鍵字： AIR CK AC API

[產(chǎn)業(yè)新聞]

以ESG賦能綠色金融發(fā)展 SGS與瑞穗銀行達(dá)成戰(zhàn)略合作

北京2022年10月9日 /美通社/ -- 近日，國(guó)際公認(rèn)的測(cè)試、檢驗(yàn)和認(rèn)證機(jī)構(gòu)SGS與瑞穗銀行（中國(guó)）有限公司（下簡(jiǎn)稱(chēng)"瑞穗銀行"）正式簽訂戰(zhàn)略合作意向書(shū)，雙方旨在ESG關(guān)聯(lián)業(yè)務(wù)方面開(kāi)啟更緊密的合作...

關(guān)鍵字：可持續(xù)發(fā)展 ISO AN OV