對于復雜的計算，單片機的速度顯得偏慢。最好的辦法是由人工事先算出全部的結(jié)果，依次存放在ROM中，程序執(zhí)行時，直接從ROM中查出結(jié)果即可。

51單片機有兩條查表指令：

MOVC A, @A + PC
MOVC A, @A + DPTR

前一條可以不用 DPTR，但是其中有個“偏移量”頗為難算，因為涉及到指令字節(jié)數(shù)的基本概念、查表等，令很多人頭痛。
做而論道針對這個問題，研究出一個自動計算偏移量的方法，可以避免煩瑣的人工計算過程。

下面是做而論道回答的一個網(wǎng)上的題目：

在 30H ~ 39H中，預先存入數(shù)據(jù)為 1，3，5，7，9，2，4，6，8，10。
利用 MOVC A, @A + PC 指令編寫一查平方表程序，將片內(nèi)30H ~ 39H內(nèi)的數(shù)求出平方后送入40H ~ 49H單元。

做而論道編寫的程序如下：
;-------------------------------------------
org 0000h

mov 30h, #1 ;先存放一些數(shù)據(jù)
mov 31h, #3
mov 32h, #5
mov 33h, #7
mov 34h, #9
mov 35h, #2
mov 36h, #4
mov 37h, #6
mov 38h, #8
mov 39h, #10

call SQRT ;調(diào)用子程序，求出上述10個數(shù)字的平方
;存放在40H開始的單元部分略
sjmp $
;-------------------------------------------
;用查表法求平方的子程序
SQRT:
MOV R0, #30H ;源數(shù)值起始地址
MOV R1, #40H ;目標起始地址
MOV R2, #10 ;共有10個數(shù)字
LOOP:
MOV A, @R0
ADD A, #S_TAB - ($ + 3) ;自動計算偏移量
MOVC A, @A + PC ;查表，求出平方
MOV @R1, A
INC R0
INC R1
DJNZ R2, LOOP
RET
;-------------------
S_TAB:
DB 0, 1, 4, 9, 16, 25, 36, 49, 64, 81, 100, 121, 144, 169, 196
;-------------------------------------------
;完

提問者對于答案的評價：恩恩 很對的 不過 #S_TAB - ($ + 3)這個什么意思??？

========================================

算法說明：

在 S_TAB 開始，用 DB 偽指令存放了一系列的《平方數(shù)字》。－－百度排版很差，引號，顯示的太小，用書名號代替。

那么，從S_TAB 開始數(shù)，第 0 個字節(jié)，就是 0 的平方，第 1 個字節(jié)，就是 1 的平方，……，第 14 個字節(jié)，就是 14 的平方。

如果，查表指令MOVC A, @A + PC 中的 PC 等于S_TAB 就好了，A 是幾，就能從表中，查出幾的平方。

呵呵，這有點像《立定跳遠》，站在跳板上，有多大的勁，就跳多遠。

而實際上，執(zhí)行查表指令MOVC A, @A + PC 時，PC，它并不等于S_TAB。

怎么辦 ？想想跳遠就知道，加上助跑，就可以了。助跑的步數(shù)或米數(shù)，大家應該都會算。

在執(zhí)行查表指令之前，把S_TAB 和執(zhí)行查表指令時的 PC 之差，算出來，加入到 A 中，即可。

這個數(shù)字，稱為偏移量，加入到 A 中，這就相當于《助跑》。

計算這個偏移量，就是要統(tǒng)計S_TAB 和執(zhí)行查表指令時的 PC 之間的字節(jié)數(shù)。

如果不熟悉機器語言，由人工計算偏移量，是相當難的。

而且，如果修改了這其中的指令，還要重新計算，非常的麻煩。

幸好，做而論道發(fā)明了自動計算偏移量的方法。

程序中，下面的兩行：

ADD A, #S_TAB - ($ + 3) ;2字節(jié)
MOVC A, @A + PC ;1字節(jié)

即完成了自動計算偏移量、查表的工作。

程序中的算式為：#S_TAB - ($ + 3)，也可以寫成：#S_TAB - $ - 3。

下面是各個部分說明：

$：代表 ADD 指令所在的當前地址；

$ + 3：即執(zhí)行查表指令時的 PC 數(shù)值，加 3，是這兩條指令共占用了三個字節(jié)；

S_TAB - ($ + 3)：求出表格首地址與查表時地址的差值；

按照單片機教材上介紹的方法，使用 MOVC A, @A + PC 指令，是要人工計算《查表指令與表首之間地址的差值》的。

用過這種方法的人，都知道有多難。

所以，絕大多數(shù)人，都寧可浪費一個 DPTR，也不愿意計算這個差值。

而做而論道研究出來的這個公式，有理論，有實踐方法，極大的方便了單片機編程人員，值得廣泛推廣。